<xsl:stylesheet version="1.0" 
    xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
    xmlns:rdfs="http://www.w3.org/2000/01/rdf-schema#"
    xmlns:xml="http://www.w3.org/XML/1998/namespace"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xml:space="default"
    xmlns:xhtml="http://www.w3.org/1999/xhtml"
    xmlns:hr="http://www.wsmo.org/ns/hrests#"
    >

    <xsl:template match="/">
        <xsl:if test="count(//*[contains(concat(' ',normalize-space(@class),' '),' service ') or 
                                contains(concat(' ',normalize-space(@rel),' '),' service ')]) > 1">
            <xsl:message terminate="yes">More than one service description in a single file not supported by this stylesheet.</xsl:message> 
            <!-- todo? - maybe support multiple services but only one rel and that only if no services are defined here -->
        </xsl:if>
        <rdf:RDF>
            <xsl:if test="//*[contains(concat(' ',normalize-space(@class),' '),' service ') or 
                              contains(concat(' ',normalize-space(@rel),' '),' service ') or
                              contains(concat(' ',normalize-space(@class),' '),' operation ') or
                              contains(concat(' ',normalize-space(@rel),' '),' operation ')
                             ]">
                <hr:Service>
                    <xsl:choose>
                        <xsl:when test="//*[contains(concat(' ',normalize-space(@class),' '),' service ')]">
                            <xsl:variable name="service" select="//*[contains(concat(' ',normalize-space(@class),' '),' service ')]"/>
                            <xsl:if test="$service/@id">
                                <xsl:attribute name="rdf:ID"><xsl:value-of select="$service/@id"/></xsl:attribute>
                            </xsl:if>
                            <rdfs:isDefinedBy rdf:resource=""/>
                            <xsl:apply-templates mode="servicelabel" select="$service" />
                            <xsl:apply-templates mode="operation" select="$service"/>
                        </xsl:when>
                        <xsl:when test="//*[contains(concat(' ',normalize-space(@rel),' '),' service ')]">
                            <rdfs:isDefinedBy rdf:resource="{//*[contains(concat(' ',normalize-space(@rel),' '),' service ')]/@href}"/>
                            <xsl:apply-templates mode="operation" select="*">
                                <xsl:with-param name="explicitDefinedBy" select="true()"/>
                            </xsl:apply-templates>
                        </xsl:when>
                        <xsl:otherwise>
                            <rdfs:isDefinedBy rdf:resource=""/>
                            <xsl:apply-templates mode="operation" select="*"/>
                        </xsl:otherwise>
                    </xsl:choose>
                </hr:Service>
            </xsl:if>
        </rdf:RDF>
    </xsl:template>

    <xsl:template match="*" mode="operation">
        <xsl:param name="explicitDefinedBy" select="false()"/>
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' operation ')">
                <hr:hasOperation>
                    <hr:Operation>
                        <xsl:if test="@id">
                            <xsl:attribute name="rdf:ID"><xsl:value-of select="@id"/></xsl:attribute>
                        </xsl:if>
                        <xsl:if test="$explicitDefinedBy">
                            <rdfs:isDefinedBy rdf:resource=""/>
                        </xsl:if>
                        <xsl:apply-templates mode="operationlabel" select="."/>
                        <xsl:choose>
                            <xsl:when test=".//*[contains(concat(' ',normalize-space(@class),' '),' method ')
                                                 and not(./ancestor::*[contains(concat(' ',normalize-space(@class),' '),' operation ') or
                                                                       contains(concat(' ',normalize-space(@class),' '),' input ') or
                                                                       contains(concat(' ',normalize-space(@class),' '),' output ')
                                                                      ]/ancestor::*[generate-id(.) = generate-id(current())])
                                                ]">
                                <xsl:apply-templates mode="operationmethod" select="*"/>
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:apply-templates mode="reverseservicemethod" select="self::*[not(contains(concat(' ',normalize-space(@class),' '),' service '))]/parent::*"/>
                                <xsl:apply-templates mode="operationmethod" select="self::*[not(contains(concat(' ',normalize-space(@class),' '),' service '))]/preceding-sibling::*"/>
                                <xsl:apply-templates mode="operationmethod" select="self::*[not(contains(concat(' ',normalize-space(@class),' '),' service '))]/following-sibling::*"/>
                            </xsl:otherwise>
                        </xsl:choose> 
                        <xsl:choose>
                            <xsl:when test=".//*[contains(concat(' ',normalize-space(@class),' '),' address ')
                                                 and not(./ancestor::*[contains(concat(' ',normalize-space(@class),' '),' operation ') or
                                                                       contains(concat(' ',normalize-space(@class),' '),' input ') or
                                                                       contains(concat(' ',normalize-space(@class),' '),' output ')
                                                                      ]/ancestor::*[generate-id(.) = generate-id(current())])
                                                ]">
                                <xsl:apply-templates mode="operationaddress" select="*"/>
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:apply-templates mode="reverseserviceaddress" select="self::*[not(contains(concat(' ',normalize-space(@class),' '),' service '))]/parent::*"/>
                                <xsl:apply-templates mode="operationaddress" select="self::*[not(contains(concat(' ',normalize-space(@class),' '),' service '))]/preceding-sibling::*"/>
                                <xsl:apply-templates mode="operationaddress" select="self::*[not(contains(concat(' ',normalize-space(@class),' '),' service '))]/following-sibling::*"/>
                            </xsl:otherwise>
                        </xsl:choose> 
                        <xsl:apply-templates mode="operationinput" select="."/>
                        <xsl:apply-templates mode="operationoutput" select="."/>
                    </hr:Operation>
                </hr:hasOperation>
            </xsl:when>
            <xsl:when test="contains(concat(' ',normalize-space(@rel),' '),' operation ')">
                <hr:hasOperation>
                    <hr:Operation>
                        <rdfs:isDefinedBy rdf:resource="{@href}"/>
                    </hr:Operation>
                </hr:hasOperation>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="operation" select="*">
                    <xsl:with-param name="explicitDefinedBy" select="$explicitDefinedBy"/>
                </xsl:apply-templates>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="*" mode="servicelabel">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' operation ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' label ')">
                <xsl:call-template name="label"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="servicelabel" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="*" mode="operationlabel">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' input ') or
                            contains(concat(' ',normalize-space(@class),' '),' output ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' label ')">
                <xsl:call-template name="label"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="operationlabel" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template name="label">
        <rdfs:label>
            <xsl:choose>
                <xsl:when test="@title"><xsl:value-of select="@title"/></xsl:when>
                <xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
            </xsl:choose>
        </rdfs:label>
    </xsl:template>

    <xsl:template match="*" mode="operationmethod">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' input ') or
                            contains(concat(' ',normalize-space(@class),' '),' output ') or
                            contains(concat(' ',normalize-space(@class),' '),' operation ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' method ')">
                <xsl:call-template name="method"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="operationmethod" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="node()" mode="reverseservicemethod">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' service ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' method ')">
                <xsl:call-template name="method"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="reverseservicemethod" select="parent::*"/>
                <xsl:apply-templates mode="operationmethod" select="preceding-sibling::*"/>
                <xsl:apply-templates mode="operationmethod" select="following-sibling::*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template name="method">
        <hr:hasMethod> 
            <xsl:variable name="value">
                <xsl:choose>
                    <xsl:when test="@title"><xsl:value-of select="@title"/></xsl:when>
                    <xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <xsl:attribute name="rdf:resource">
                <xsl:choose>
                    <xsl:when test="$value='GET'    or $value='get'    or $value='Get'"   >http://www.wsmo.org/ns/hrests#GET</xsl:when>
                    <xsl:when test="$value='PUT'    or $value='put'    or $value='Put'"   >http://www.wsmo.org/ns/hrests#PUT</xsl:when>
                    <xsl:when test="$value='POST'   or $value='post'   or $value='Post'"  >http://www.wsmo.org/ns/hrests#POST</xsl:when>
                    <xsl:when test="$value='DELETE' or $value='delete' or $value='Delete'">http://www.wsmo.org/ns/hrests#DELETE</xsl:when>
                    <xsl:otherwise>
                        <xsl:message terminate="yes">Unknown HTTP method: <xsl:value-of select="$value"/></xsl:message>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:attribute>
        </hr:hasMethod>
    </xsl:template>


    <xsl:template match="*" mode="operationaddress">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' input ') or
                            contains(concat(' ',normalize-space(@class),' '),' output ') or
                            contains(concat(' ',normalize-space(@class),' '),' operation ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' address ')">
                <xsl:call-template name="address"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="operationaddress" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="node()" mode="reverseserviceaddress">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' service ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' address ')">
                <xsl:call-template name="address"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="reverseserviceaddress" select="parent::*"/>
                <xsl:apply-templates mode="operationaddress" select="preceding-sibling::*"/>
                <xsl:apply-templates mode="operationaddress" select="following-sibling::*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template name="address">
        <hr:hasAddress rdf:datatype="http://www.wsmo.org/ns/hrests#URITemplate">
            <xsl:choose>
                <xsl:when test="@title"><xsl:value-of select="@title"/></xsl:when>
                <xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
            </xsl:choose>
        </hr:hasAddress>
    </xsl:template>

    <xsl:template match="*" mode="operationinput">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' output ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' input ')">
                <xsl:call-template name="input"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="operationinput" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="*" mode="operationoutput">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' input ')" />
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' output ')">
                <xsl:call-template name="output"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="operationoutput" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template name="input">
        <hr:hasInputMessage>
            <hr:Message>
                <xsl:if test="@id">
                    <xsl:attribute name="rdf:ID"><xsl:value-of select="@id"/></xsl:attribute>
                </xsl:if>
                <xsl:apply-templates mode="messagelabel" select="."/>
            </hr:Message>
        </hr:hasInputMessage>
    </xsl:template>

    <xsl:template name="output">
        <hr:hasOutputMessage>
            <hr:Message>
                <xsl:if test="@id">
                    <xsl:attribute name="rdf:ID"><xsl:value-of select="@id"/></xsl:attribute>
                </xsl:if>
                <xsl:apply-templates mode="messagelabel" select="."/>
            </hr:Message>
        </hr:hasOutputMessage>
    </xsl:template>

    <xsl:template match="*" mode="messagelabel">
        <xsl:choose>
            <xsl:when test="contains(concat(' ',normalize-space(@class),' '),' label ')">
                <xsl:call-template name="label"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates mode="messagelabel" select="*"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <!-- todo add support for link and form operations -->


</xsl:stylesheet>